Windows下bat批处理命令完成执行ftp文件上传并实现邮件推送

前言
快速上手
- ftp文件传输命令调用
整体过程
知识点

前言

本系列文章讲述了如何开启ftp服务，控制文档存储路径，实现按时间创建远程文件夹并将文件上传到文件夹，并发送通知报告及文件展示的过程。
本章讲解Windows下bat批处理命令完成执行ftp文件上传并实现邮件推送的过程
文件服务器为Linux机器

快速上手

ftp文件传输命令调用

将内容保存至sendReport.bat文件后直接执行以下命令

cmd或其他方式直接的bat命令

:: F:\aa 文件路径 \myreport.html 文件名
call sendReport.bat F:\aa myreport.html

FTP上传简单命令（将内容保存至sendReport.bat文件）

::::::::::::::::: FTP命令文件生成:::::::::::::::::
set FTPC=fileCommand.ftpc
(
::路径
echo open 10.24.22.115
:: 用户名
echo ftpuser
:: 密码
echo pswispsw
::send 第一个参数:本地上传文件路径和名称 第二个参数：接收到的文件路径和名称（不写则上传到cd的路径）(%1 获取传入的第1个参数)
echo send %1
::bye 退出ftp
echo bye
)>%FTPC%
::send 为获取 第一个参数为本地上传文件路径和名称 第二个参数为接收到的文件路径和名称（不写则上传到cd的路径）
::::::::::::::::: FTP上传指令执行:::::::::::::::::
ftp -s:%FTPC%

具体参数案例见附件

整体过程

初始化命令 init.bat

将一些参数初始到系统变量中，以便其他bat调用，仅在部署时调用一次即可
初始化的变量CODEREVIEW为代码所在位置
赋权限需要提权

@echo off

:: 提权操作
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
 
    "%temp%\getadmin.vbs"
    exit /B 

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"

:: 初始化变量 CODEREVIEW：bat代码根目录
SETX  /M  CODEREVIEW F:\codeview-ci
set path_=%Path%
setx “Path” “%path_%;newpath1;newpath2” /m
::等待以便确认是否成功

pause

成功标志
在这里插入图片描述

扫描F:\aa\demo2的代码并上传文件发送报告的命令：

run.bat F:\aa\demo2

运行命令run.bat

具体执行findbugs命令，完成后执行文件上传

call findbugs -textui -low -html:fancy-hist.xsl -output %CODEREVIEW%\myreport.html %1
:: F:\aa 文件路径 \myreport.html 文件名 \receiveDir接收路径 
call %CODEREVIEW%\sendReport.bat F:\aa myreport.html

文件上传 sendReport.bat

实现功能：按时间创建远程文件夹，将文件上传至此，完成后发送邮件通知

@echo off
::若生成文件乱码则取消以下代码的注释 chcp 65001
::::::::::::::::: 按时间生成文件夹:::::::::::::::::
set filename=%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%
set "filename=%filename: =0%"
::::::::::::::::: FTP命令文件生成:::::::::::::::::
set FTPC=%CODEREVIEW%\log\%filename%.ftpc
(
echo open 10.24.22.115
echo ftpuser
echo pswispsw
echo lcd %1
echo mkdir %filename%
echo cd %filename%
echo send %2
echo bye
)>%FTPC%
::::::::::::::::: FTP上传指令执行:::::::::::::::::
ftp -s:%FTPC%
::::::::::::::::: 发送邮件指令:::::::::::::::::
call  %CODEREVIEW%\sendMail.bat %filename%

生成的文件名：
为保证时间的正确性，需在windows机器上使用echo %date%确定一下date的值是日期在前，还是周在前，如周在前需要将
set filename=%date:~0,4%%date:~5,2%%date:~8,2%%time:~0,2%%time:~3,2%%time:~6,2%
改为
set filename=%date:~3,4%%date:~8,2%%date:~11,2%%time:~0,2%%time:~3,2%%time:~6,2%
在这里插入图片描述

发送邮件 sendMail.bat

@echo off 
::::::::::::::::: 初始变量 :::::::::::::::::
set bodyname=%1
set mailB=%CODEREVIEW%\log\body-%bodyname%.mailb
::::::::::::::::: 邮件内容 :::::::::::::::::
(
echo 以下内容为系统自动发送，请勿直接回复，谢谢！
echo 各位领导及同事好！
echo 您提交的代码审查任务已完成测试，请根据以下网址进行结果查看：
echo http://10.24.22.115/obvious/%bodyname%/myreport.html
)>>%mailB%

::::::::::::::::: 参数设置 :::::::::::::::::
set from=8sender@qq.com
set user=8sender
set pass=password
set to=receive@shaojs.cn,receive2@shaojs.cn
set subj=报告结果
set mail=%mailB%
:: 添加附件
:: set attach=body.txt
set server=smtp.qq.com
set debug=-debug -log blat.log -timestamp
::::::::::::::::: 运行blat :::::::::::::::::
blat %mail% -to %to%  -charset Gb2312 -subject %subj% -server %server% -f %from% -u %user% -pw %pass% %debug%

发送邮件使用了balt小工具，具体请移步：简单文件服务器(4)-Windows下bat批处理命令发送邮件

知识点

bat相关

设置环境变量需要bat获取到管理员权限

具体请回到init.bat

setx

:: REM 和::都是常见的bat注释

REM setx为设置用户环境变量
setx NAME "sam"
REM setx /m 为设置系统环境变量
setx NAME "sam" /m

FTP命令大全:

回到快速上手

FTP的命令行格式为： ftp -v -d -i -n -g [主机名] ，其中 -v 显示远程服务器的所有响应信息；
-n 限制ftp的自动登录，即不使用；.n etrc文件；
-d 使用调试方式；
-g 取消全局文件名。 FTP使用的内部命令如下(中括号表示可选项):
1.![cmd[args>：在本地机中执行交互shell，exit回到ftp环境，如：!ls*.zip
2.$ macro-ame[args]：执行宏定义macro-name。
3.account[password]：提供登录远程系统成功后访问系统资源所需的补充口令。
4.append local-file[remote-file]：将本地文件追加到远程系统主机，若未指定远程系统文件名，则使用本地文件名。
5.ascii：使用ascii类型传输方式。
6.bell：每个命令执行完毕后计算机响铃一次。
7.bin：使用二进制文件传输方式。
8.bye：退出ftp会话过程。
9.case：在使用mget时，将远程主机文件名中的大写转为小写字母。
10.cd remote-dir：进入远程主机目录。
11.cdup：进入远程主机目录的父目录。
12.chmod mode file-name：将远程主机文件file-name的存取方式设置为mode，如：chmod 777 a.out。
13.close：中断与远程服务器的ftp会话(与open对应)。
14.cr：使用asscii方式传输文件时，将回车换行转换为回行。
15.delete remote-file：删除远程主机文件。
16.debug[debug-value]：设置调试方式，显示发送至远程主机的每条e5a48de588b6e79fa5e9819331333337396265命令，如：deb up
3，若设为0，表示取消debug。
17.dir[remote-dir][local-file]：显示远程主机目录，并将结果存入本地文件
18.disconnection：同close。
19.form format：将文件传输方式设置为format，缺省为file方式。
20.get remote-file[local-file]：将远程主机的文件remote-file传至本地硬盘的local-file。
21.glob：设置mdelete，mget，mput的文件名扩展，缺省时不扩展文件名，同命令行的-g参数。
22.hash：每传输1024字节，显示一个hash符号(#)。
23.help[cmd]：显示ftp内部命令cmd的帮助信息，如：help get。
24.idle[seconds]：将远程服务器的休眠计时器设为[seconds]秒。
25.image：设置二进制传输方式(同binary)。
26.lcd[dir]：将本地工作目录切换至dir。
27.ls[remote-dir][local-file]：显示远程目录remote-dir，并存入本地文件local-file。
28.macdef macro-name：定义一个宏，遇到macdef下的空行时，宏定义结束。
29.mdelete[remote-file]：删除远程主机文件。
30.mdir remote-files local-file：与dir类似，但可指定多个远程文件，如：mdir .o..zipoutfile 。
31.mget remote-files：传输多个远程文件。
32.mkdir dir-name：在远程主机中建一目录。
33.mls remote-file local-file：同nlist，但可指定多个文件名。
34.mode[modename]：将文件传输方式设置为modename，缺省为stream方式。
35.modtime file-name：显示远程主机文件的最后修改时间。
36.mput local-file：将多个文件传输至远程主机。
37.newer file-name：如果远程机中file-name的修改时间比本地硬盘同名文件的时间更近，则重传该文件。
38.nlist[remote-dir][local-file]：显示远程主机目录的文件清单，并存入本地硬盘的local-file。
39.nmap[inpattern outpattern]：设置文件名映射机制，使得文件传输时，文件中的某些字符相互转换，如：nmap $1.$2.$3[$1，$2].[$2，$3]，则传输文件a1.a2.a3时，文件名变为a1，a2。
该命令特别适用于远程主机为非UNIX机的情况。
40.ntrans[inchars[outchars>：设置文件名字符的翻译机制，如ntrans1R，则文件名LLL将变为RRR。
41.open host[port]：建立指定ftp服务器连接，可指定连接端口。
42.passive：进入被动传输方式。
43.prompt：设置多个文件传输时的交互提示。
44.proxy ftp-cmd：在次要控制连接中，执行一条ftp命令，该命令允许连接两个ftp服务器，以在两个服务器间传输文件。第一条ftp命令必须为open，以首先建立两个服务器间的连接。
45.put local-file[remote-file]：将本地文件local-file传送至远程主机。
46.pwd：显示远程主机的当前工作目录。
47.quit：同bye，退出ftp会话。
48.quote arg1，arg2…：将参数逐字发至远程ftp服务器，如：quote syst.
49.recv remote-file[local-file]：同get。
50.reget remote-file[local-file]：类似于get，但若local-file存在，则从上次传输中断处续传。
51.rhelp[cmd-name]：请求获得远程主机的帮助。
52.rstatus[file-name]：若未指定文件名，则显示远程主机的状态，否则显示文件状态。
53.rename[from][to]：更改远程主机文件名。
54.reset：清除回答队列。
55.restart marker：从指定的标志marker处，重新开始get或put，如：restart 130。
56.rmdir dir-name：删除远程主机目录。
57.runique：设置文件名只一性存储，若文件存在，则在原文件后加后缀.1， .2等。
58.send local-file[remote-file]：同put。
59.sendport：设置PORT命令的使用。
60.site arg1，arg2…：将参数作为SITE命令逐字发送至远程ftp主机。
61.size file-name：显示远程主机文件大小，如：site idle 7200。
62.status：显示当前ftp状态。
63.struct[struct-name]：将文件传输结构设置为struct-name，缺省时使用stream结构。
64.sunique：将远程主机文件名存储设置为只一(与runique对应)。
65.system：显示远程主机的操作系统类型。
66.tenex：将文件传输类型设置为TENEX机的所需的类型。
67.tick：设置传输时的字节计数器。
68.trace：设置包跟踪。
69.type[type-name]：设置文件传输类型为type-name，缺省为ascii，如:type binary，设置二进制传输方式。
70.umask[newmask]：将远程服务器的缺省umask设置为newmask，如：umask 3
71.user user-name[password][account]：向远程主机表明自己的身份，需要口令时，必须输入口令，如：user anonymous my@email。
72.verbose：同命令行的-v参数，即设置详尽报告方式，ftp 服务器的所有响应都将显示给用户，缺省为on.

简单文件服务器-Windows下bat批处理命令执行findbugs代码审查、ftp文件上传、邮件推送