这篇文章讲述的是pl/sql操作数据库之异常处理,如有错误或者不当之处,希望各位大神批评指正。
什么是异常处理?
- 异常情况处理(EXCEPTION)是用来处理正常执行过程中未预料的事件,程序块的异常处理预定义的错误和自定义错误,由于PL/SQL程序块一旦产生异常而没有指出如何处理时,程序就会自动终止整个程序运行.
- 一个优秀的程序都应该能够正确处理各种出错情况,并尽可能从错误中恢复
oracle中异常的分类
- oracle数据库中的异常大致分为三类:
- 预定义异常(Predefined )
- 非预定义异常( UnPredefined )
- 自定义异常(User_define)
预定义异常
ORACLE预定义的异常情况大约有24个。对这种异常情况的处理,无需在程序中定义,由ORACLE自动将其引发。
预定义异常:
错误号 | 异常错误信息名称 | 说明 |
---|---|---|
ORA-0001 | Dup_val_on_index | 试图破坏一个唯一性限制 |
ORA-0051 | Timeout-on-resource | 在等待资源时发生超时 |
ORA-0061 | Transaction-backed-out | 由于发生死锁事务被撤消 |
ORA-1001 | Invalid-CURSOR | 试图使用一个无效的游标 |
ORA-1012 | Not-logged-on | 没有连接到ORACLE |
ORA-1017 | Login-denied | 无效的用户名/口令 |
ORA-1403 | No_data_found | SELECT INTO没有找到数据 |
ORA-1422 | Too_many_rows | SELECT INTO 返回多行 |
ORA-1476 | Zero-divide | 试图被零除 |
ORA-1722 | Invalid-NUMBER | 转换一个数字失败 |
ORA-6500 | Storage-error | 内存不够引发的内部错误 |
ORA-6501 | Program-error | 内部错误 |
ORA-6502 | Value-error | 转换或截断错误 |
ORA-6504 | Rowtype-mismatch | 缩主游标变量与 PL/SQL变量有不兼容行类型 |
ORA-6511 | CURSOR-already-OPEN | 试图打开一个已存在的游标 |
ORA-6530 | Access-INTO-null | 试图为null 对象的属性赋值 |
ORA-6531 | Collection-is-null | 试图将Exists 以外的集合( collection)方法应用于一个null pl/sql 表上或varray上 |
ORA-6532 | Subscript-outside-limit | 对嵌套或varray索引得引用超出声明范围 |
ORA-6533 | Subscript-beyond-count | 对嵌套或varray 索引得引用大于集合中元素的个数. |
非预定义异常
- 即其他标准的ORACLE错误。对这种异常情况的处理,需要用户在程序中定义,然后由ORACLE自动将其引发。
自定义异常
- 程序执行过程中,出现编程人员认为的非正常情况。对这种异常情况的处理,需要用户在程序中定义,然后显式地在程序中将其引发。
异常的处理
- 异常处理的格式为:
EXCEPTION
WHEN first_exception THEN <code to handle first exception >
WHEN second_exception THEN <code to handle second exception >
WHEN OTHERS THEN <code to handle others exception >
END;
预定义异常的处理
- 假设有表student若查询学生年龄时结果大于一行,则抛出异常‘发生异常,结果大于一行’
declare
v_age student.age%Type ;
begin
select age into v_age
from student
where id > 100001 ;
dbms_output.put_line(v_age);
exception
--异常处理
when Too_many_rows then dbms_output.put_line('发生异常,结果大于一行');
when others then dbms_output.put_line('发生其他异常');
end ;
非预定义异常的处理
非预定义异常的处理要经过一下步骤:
- 定义异常
<异常情况> EXCEPTION
- 将其定义好的异常情况,与标准的ORACLE错误联系起来
PRAGMA EXCEPTION_INIT(<异常情况>, <错误代码>)
- 在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理
- 定义异常
假设有表teacher,student,其中student外键t_id关联teacher中的id,定义一个异常若教师名下有学生时发生异常‘删除错误,外键依赖不为空’
declare
--定义异常
e_delete_std_exception exception ;
--关联异常
pragma EXCEPTION_INIT(e_delete_std_exception,-02292) ;
begin
delete
from teacher
where t_id = 200001 ;
dbms_output.put_line('删除成功');
exception
--处理异常
when e_delete_std_exception then dbms_output.put_line('删除错误,外键依赖不为空');
end ;
自定义异常的处理
当与一个异常错误相关的错误出现时,就会隐含触发该异常错误。用户定义的异常错误是通过显式使用 RAISE 语句来触发。当引发一个异常错误时,控制就转向到 EXCEPTION块异常错误部分,执行错误处理代码。
自定义异常的处理需要如下几步:
- 在PL/SQL 块的定义部分定义异常情况
<异常情况> EXCEPTION
- 发起异常
RAISE <异常情况>
- 在PL/SQL 块的异常情况处理部分对异常情况做出相应的处理
- 在PL/SQL 块的定义部分定义异常情况
定义一个异常,当查询表中学生性别不为‘男’或‘女’时抛出异常‘异常发生,该学生性别不合法’
declare
v_sex student.sex%Type ;
--定义异常
e_sexnull_exception exception ;
begin
select sex into v_sex
from student
where id = 100006 ;
--发起异常
if v_sex!='F' and v_sex!='M'
then raise e_sexnull_exception ;
end if ;
dbms_output.put_line(v_sex);
exception
--处理异常
when e_sexnull_exception then dbms_output.put_line('异常发生,该学生性别不合法');
when No_data_found then dbms_output.put_line('异常发生,未找到该学生');
end ;