FPGA之按键消抖

按键是一种常用的人机交互输入接口，对于机械按键来说，在按下或弹起的时候，按键输入值往往伴随着输入抖动。消除抖动的方式有很多种，以下是用FPGA实现按键消抖。实现原理：当检测到按键按下（一般按下为低电平）时开始计时（用计数器实现），大概10ms后检测按键状态，如果按键状态为低电平，说明按键按下，输出低电平；如果按键状态为高电平，说明是按键抖动。按键弹起同理。
下面对按键消抖的代码（ax_debounce.v）进行分析：

module ax_debounce(
input clk,
input rst,
input button_in,
output reg button_posedge,
output reg button_negedge,
output reg button_out
);

ax_debounce模块定义：时钟输入引脚clk、复位引脚rst、按键输入引脚button_in。按键上升沿输出寄存器、按键下降沿输出寄存器和按键状态输出寄存器。

assign q_reset = (DEF1 ^ DEF2);

通过按键的两个输入寄存器异或来检测按键输入的电平变化。

assign q_add = ~(q_reg == TIMER_MAX_VAL);

通过寄存器q_reg累加后与TIMER_MAX_VAL进行判断，从而确定是否到达按键消抖时间。

always @(q_reset, q_add, q_reg)
begin
	case ({q_reset, q_add})
		2'b00:
			q_next <= q_reg;
		2'b01:
			q_next <= q_reg + 1;
		default:
			q_next <= {N{1'b0}};
	endcase
end

以上代码用于时间计数，计数值保存到q_next中。

always @(posedge clk or posedge rst)
begin
	if(rst == 1'b1)
		begin
			DEF1 <= 1'b0;
			DEF2 <= 1'b0;
			q_reg <= {N{1'b0}};
		end
	else
		begin
			DEF1 <= button_in;
			DEF2 <= DEF1;
			q_reg <= q_next;
		end 
end

以上代码用于实时记录按键输入状态，并依次保存到DEF1 和DEF2中。

always @(posedge clk or posedge rst)
	begin
		if(rst == 1'b1)
			button_out <= 1'b1;
		else if(q_reg == TIMER_MAX_VAL)
			button_out <= DEF2;
		else
			button_out <= button_out;    
end

以上代码表示按键状态变化时把DEF2赋给按键输出寄存器。

always @(posedge clk or posedge rst)
	begin
		if(rst == 1'b1)
			begin
				button_out_d0 <= 1'b1;
				button_posedge <= 1'b0;
				button_negedge <= 1'b0;
			end
		else
			begin
				button_out_d0 <= button_out;
				button_posedge <= ~button_out_d0&button_out;
				button_negedge <= button_out_d0& ~button_out;
		end
	end
endmodule

以上代码通过button_posedge和button_negedge的值来判断当前的按键状态是按键按下还是弹起。

猜你喜欢