漫反射
漫反射根据就算位置不同分为逐顶点漫反射和逐像素漫反射。
（1）在顶点着色器中计算。 此方法称为 逐顶点光照 或 高洛德着色（Gouraud shading）, 在每个顶点上计算光照，然后在渲染图元内部进行线性插值，输出成像素颜色。而顶点数目通常会远小于像素数目，所以逐顶点光照的计算量往往更小
（2）在片元着色器中计算。此方法称为 逐像素光照 或 Phong着色（Phong shading），以每个像素为基础，得到它的法线（可以对顶点法线插值得到，也可以从法线纹理中采样得到）
漫反射计算公式：漫反射颜色 = 直射光颜色 * max(0, cos(光源方向和法线方向夹角)) * 材质自身色彩
逐顶点漫反射
Shader "Unlit/Vertex diffuse"//逐顶点漫反射
{
Properties
{
_Diffuse("Diffuse",Color) = (0,0,0,0)
}
SubShader
{
Tags {
"RenderType" = "Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _Diffuse;
struct v2f {
float4 vertex:SV_Position;
fixed3 color : Color;
};
v2f vert (appdata_base v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
//环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//将法线转换到世界坐标
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
//光源方向归一化
fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
//漫反射Diffuse颜色 = 直射光颜色* 材质自身色彩 * saturate(dot(光源方向和法线方向夹角)) saturate（x）:把x限制到【0,1】之间
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
//加上环境光（亮度增加）
o.color = diffuse+ ambient;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
return fixed4(i.color,1);
}
ENDCG
}
}
}
逐像素漫反射
Shader "Unlit/Phong"//逐片元漫反射
{
Properties
{
_Diffuse("Diffuse",Color) = (0,0,0,0)
}
SubShader
{
Tags {
"RenderType" = "Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
fixed4 _Diffuse;
struct v2f {
float4 vertex:SV_Position;
fixed3 worldNormal : TEXCOORD0;
};
v2f vert(appdata_base v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
//将法线转换到世界坐标
o.worldNormal = UnityObjectToWorldNormal(v.normal);
return o;
}
fixed4 frag(v2f i) : SV_Target
{
//环境光
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//光源方向
fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
//漫反射Diffuse = 直射光颜色* 材质自身色彩 * max(dot(光源方向和法线方向夹角))
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldLightDir, i.worldNormal));
//加上环境光（亮度增加）
fixed3 color = diffuse + ambient;
return fixed4(color,1);
}
ENDCG
}
}
}
左边逐顶点，右边逐片元
对比可以看到，逐片元光照实现的效果比逐顶点更加平滑。不过即便如此，在光照无法到达的区域依旧是全黑的。如果添加了环境光就可以达到非全黑的效果，但是此时，模型背光面明暗会一样。而针对这一情况所提出的技术就是 半兰伯特（Half Lambert）光照模型
注意:
（1）颜色融合是相乘，颜色叠加是相加（通常亮度会增加）。
（2）逐像素计算光照要比逐顶点计算光照更加消耗性能。
半兰伯特（Half Lambert）光照模型
只需要将
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * max(0, dot(worldLightDir, i.worldNormal));
改为
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * dot(worldLightDir, i.worldNormal)*0.5 + 0.5;
三种光照模型对比
高光反射
高光反射同样分为逐顶点和逐片元
逐顶点高光反射
高光反射公式：
Specular= 直射光颜色 * pow（max（dot（当前点的反射光方向，当前点到摄像机的方向），0），高光反射参数）
Shader "Unity/008"
{
Properties
{
_Diffuse("Diffuse",Color) = (1,1,1,1)
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(8.0,256)) = 20
}
SubShader
{
Pass
{
Tags {
"LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
fixed3 color : COLOR;
};
v2f vert(a2v v)
{
v2f o;
//顶点信息转换至世界空间
o.pos = UnityObjectToClipPos(v.vertex);
//得到环境光部分
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//顶点法线转换至世界空间
fixed3 worldnormal = normalize(mul(v.normal,(float3x3)unity_WorldToObject));
//光源方向
fixed3 worldlight = normalize(_WorldSpaceLightPos0.xyz);
//漫反射部分
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldnormal,worldlight));
//计算反射方向。 reflect 函数的入射方向是由光源指向交点的，所以这里的参数要取负
fixed3 reflectDir = normalize(reflect(-worldlight,worldnormal));
//计算视角方向
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld,v.vertex).xyz);
//得到高光发射部分
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir,viewDir)),_Gloss);
o.color = ambient + diffuse + specular;
return o;
}
fixed4 frag(v2f i) : SV_Target
{
return fixed4(i.color,1.0);
}
ENDCG
}
}
FallBack "Specular"
}
逐片元高光反射
Shader "Unlit/009"
{
Properties
{
_Diffuse("Diffuse",Color) = (1,1,1,1)
_Specular("Specular",Color) = (1,1,1,1)
_Gloss("Gloss",Range(8.0,256)) = 20
}
SubShader
{
Pass
{
Tags {
"LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
fixed4 _Diffuse;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f {
float4 pos : SV_POSITION;
fixed3 worldnormal : TEXCOORD0;
float3 worldPos : TEXCOORD1;
};
v2f vert(a2v v)
{
v2f o;
//顶点信息转换至世界空间
o.pos = UnityObjectToClipPos(v.vertex);
o.worldnormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
o.worldPos = UnityObjectToClipPos(v.vertex).xyz;
return o;
}
fixed4 frag(v2f i) : SV_Target
{
//得到环境光部分
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
//顶点法线转换至世界空间
fixed3 worldnormal = i.worldnormal;
//光源方向
fixed3 worldlight = normalize(_WorldSpaceLightPos0.xyz);
//漫反射部分
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldnormal, worldlight));
//计算反射方向。 reflect 函数的入射方向是由光源指向交点的，所以这里的参数要取负
fixed3 reflectDir = normalize(reflect(-worldlight, worldnormal));
//计算视角方向
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
//得到高光发射部分
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
return fixed4(ambient+ diffuse+ specular,1.0);
}
ENDCG
}
}
FallBack "Specular"
}
