Win32汇编实现终止进程

具体代码实现

    .386  ;汇编语言的伪指令
    .model flat,stdcall
    option casemap:none

include         windows.inc
include         user32.inc
includelib      user32.lib
include         kernel32.inc
includelib      kernel32.lib
include         msvcrt.inc
includelib      msvcrt.lib
    
    .data
szFmt     db  '%s', 0

    .data?
szBuffer      db 256 dup(?)  
ProcessId     dd ?

    .const
szGetStdHandleError     db "GetStdHandle error!",0
szOpenProcessError      db "OpenProcess error!",0
szTerminateProcess      db "TerminateProcess error!",0
szKillProcSuccess       db "Kill it success!",0
;对话框标题
szErrorCaption          db "Some Error!",0
szSuccessCaption        db "Success!",0
szMessage               db "enter the process id that you want to kill: ",0   

    .code
;atoi 字符转换为整型
atoi proc uses ecx edi edx esi,string:DWORD

      mov edi, string
      invoke lstrlen,string
      xor ecx, ecx ;存结果
      .while eax != 0
        xor edx, edx
        mov dl, byte ptr [edi]
        sub dl, 30h ;
        mov esi, eax
        dec esi
        push eax
        mov eax, edx
        push ebx
        mov ebx, 10
          .while esi > 0
            mul ebx
            dec esi
          .endw
        pop ebx
        add ecx, eax
        pop eax
        inc edi
        dec eax
      .endw
	  mov eax, ecx
      ret
atoi endp

;输出出错信息，并退出
ErrorExit proc ErrorMsg
        invoke MessageBox,NULL,ErrorMsg,offset szErrorCaption,MB_OK
        invoke ExitProcess,NULL 
ErrorExit endp

;根据进程号杀死进程
KillProcess proc procid
        local @hProcess
        invoke OpenProcess,PROCESS_TERMINATE,FALSE,procid
        mov @hProcess,eax;invoke返回值存放在eax
        .if eax == NULL
            invoke ErrorExit,offset szOpenProcessError
        .endif
        ;杀死进程
        invoke TerminateProcess,@hProcess,NULL
        .if eax == NULL
            invoke ErrorExit,offset szTerminateProcess
        .endif
        invoke MessageBox,NULL,offset szKillProcSuccess,offset szSuccessCaption,MB_OK
        ret
KillProcess endp

start:
        invoke crt_printf, addr szMessage
        invoke crt_scanf,addr szFmt,addr szBuffer 
        invoke atoi,offset szBuffer;eax存放着ProcessId
        mov ProcessId,eax
        invoke KillProcess,ProcessId
        invoke ExitProcess,NULL
    end start

参考C语言

#include<stdio.h>
#include<windows.h>
void main(int arg,char* args[])
{
    
    	
	int pid = atoi(args[1]);	
	DWORD p = (DWORD)pid;	
	KillProcess(pid));	
}
void KillProcess(DWORD ProcessId){
    
    	
HANDLE hProcess=OpenProcess(PROCESS_TERMINATE,FALSE,ProcessId);	
	if(hProcess==NULL)
	{
    
    
		printf("OpenProcess error!");
		exit(1);
	}
	if(!TerminateProcess(hProcess,0))
	{
    
    
		printf("TerminateProcess error!");
		exit(1);
	}
printf("Kill it success!");
}