grep 文本搜索工具
sed 文本编辑工具
awk 文本格式化工具
awk语法
awk [options] '/pattern{action}'
options -F
pattern:
定界 addr1，addr2
表达式 $3 > 500
/pattern/ 模式
BEGIN{} 在遍历操作开始之前执行一次
END{} 在遍历操作结束之后、命令退出之前执行一次
action
print，printf 用于能够实现格式化输出的工具
awk编程语言：变量、数组、选择、循环、内置函数、自定义函数
一、print
print的使用格式：
print item1, item2, ...
要点：
1、各项目之间使用逗号隔开，而输出时则以空白字符分隔；
awk -F: '/^root/{print $1,$7}' /etc/passwd
2、输出的item可以为字符串或数值、当前记录的字段(如$1)、变量或awk的表达式；数值会先转换为字符串，而后再输出；
awk 'BEGIN { print "line one\nline two\nline three" }'
3、print命令后面的item可以省略，此时其功能相当于print $0, 因此，如果想输出空白行，则需要使用print ""；
awk 'BEGIN{print ""}'
二、awk变量
2.1 awk内置变量之记录变量：
FS: field separator 读取文件本时，所使用字段分隔符；默认为空格 awk 'BEGIN{FS=":"} {print $1}' /etc/passwd
OFS: Output Filed Separator 输出文件本时，所使用字段分隔符；默认为空格 awk 'BEGIN{FS=":";OFS=":"} {print$1,$7}' /etc/passwd
RS: Record separator 输入文本信息所使用的换行符；默认会回车换行 awk 'BEGIN{RS=" "} {print $0}' /etc/passwd
ORS：Output Row Separator 输出文本信息所使用的换行符；默认会回车换行 awk 'BEGIN{ORS="*********"} {print $0}' /etc/passwd
2.2 awk内置变量之数据变量：
NR: The number of input records，awk命令所处理的记录数；如果有多个文件，这个数目会把处理的多个文件中行统一计数；
NF：Number of Field，当前记录的field个数；
FNR: 与NR不同的是，FNR用于记录正处理的行是当前这一文件中被总共处理的行数；
ARGV: 数组，保存命令行本身这个字符串，如awk '{print $0}' a.txt b.txt这个命令中，ARGV[0]保存awk，ARGV[1]保存a.txt；
ARGC: awk命令的参数的个数；
FILENAME: awk命令所处理的文件的名称；在命令中获取当前文件名
ENVIRON：当前shell环境变量及其值的关联数组；
awk '{print NR,$0}' /etc/fstab /etc/issue
awk '{print NF $0}' /etc/issue
awk '{print FNR,$0}' /etc/fstab /etc/issue
awk '/^root/{print ARGV[0],ARGV[1],ARGV[2]}' /etc/issue /etc/fstab
awk '{print ARGC}' /etc/issue /etc/fstab
awk '{print $0, "in", FILENAME}' /etc/issue /etc/fstab
awk 'BEGIN{print ENVIRON["PATH"]}'
做计算器使用 awk "BEGIN{print 1+2}"
2.3 用户自定义变量
gawk允许用户自定义自己的变量以便在程序代码中使用，变量名命名规则与大多数编程语言相同，只能使用字母、数字和下划线，且不能以数字开头。gawk变量名称区分字符大小写。
-v：自定义变量
awk -v num1=20 -v num2=32 'BEGIN{print num1+num2}'
awk 'BEGIN{num1=20;num2=32;print num1+num2}'
2.3.1 在脚本中赋值变量
在gawk中给变量赋值使用赋值语句进行，例如：
awk 'BEGIN{num1=20;num2=32;print num1+num2}'
2.3.2 在命令行中使用赋值变量
gawk命令也可以在“脚本”外为变量赋值，并在脚本中进行引用。例如，上述的例子还可以改写为：
awk -v num1=20 -v num2=32 'BEGIN{print num1+num2}'
三、printf
printf命令的使用格式：
printf format, item1, item2, ...
要点：
1、其与print命令的最大不同是，printf需要指定format；
2、format用于指定后面的每个item的输出格式；
3、printf语句不会自动打印换行符；\n
format格式的指示符都以%开头，后跟一个字符；如下：
%c: 显示字符的ASCII码；
%d, %i：十进制整数；
%e, %E：科学计数法显示数值；
%f: 显示浮点数；
%g, %G: 以科学计数法的格式或浮点数的格式显示数值；
%s: 显示字符串；
%u: 无符号整数；
%%: 显示%自身；
修饰符：
N: 显示宽度；
-: 左对齐；
+：显示数值符号；
awk 'BEGIN{num1=2018;num2=2019;printf "%d %d\n",num1,num2}'
awk -F : '{printf "%-10s %s\n",$1,$NF}' /etc/passwd 以字符串方式显示，左对齐，显示宽度为10个字符
四、输出重定向
print items > output-file
print items >> output-file
print items | command
特殊文件描述符：
/dev/stdin 标准输入
/dev/sdtout 标准输出
/dev/stderr 错误输出
/dev/fd/N 某特定文件描述符，如/dev/stdin就相当于/dev/fd/0；
例子：
# awk -F: '{printf "%-15s %i\n",$1,$3 > "/tmp/output" }' /etc/passwd
五、awk的操作符：
5.1 算术操作符：
-x: 负值
+x: 转换为数值；
x^y: 次方
x**y: 次方
x*y: 乘法
x/y：除法
x+y:
x-y:
x%y:
awk 'BEGIN{print 3%2}'
5.2 字符串操作符：
只有一个，而且不用写出来，用于实现字符串连接；
5.3 赋值操作符：
=
+=
-=
*=
/=
%=
^=
**=
++
--
需要注意的是，如果某模式为=号，此时使用/=/可能会有语法错误，应以/[=]/替代；
5.4 布尔值
awk中，任何非0值或非空字符串都为真，反之就为假；
5.5 比较操作符：
x < y True if x is less than y.
x <= y True if x is less than or equal to y.
x > y True if x is greater than y.
x >= y True if x is greater than or equal to y.
x == y True if x is equal to y.
x != y True if x is not equal to y.
x ~ y True if the string x matches the regexp denoted by y. x能被模式y匹配
x !~ y True if the string x does not match the regexp denoted by y. x不能被模式y匹配
subscript in array True if the array array has an element with the subscript subscript. 数组下标遍历
5.7 表达式间的逻辑关系符：
&&
||
5.8 条件表达式：
selector?if-true-exp:if-false-exp
awk -v num1=11 -v num2=22 'BEGIN{num1>num2?max=num1:max=num2;print max}'
5.9 函数调用：
function_name(para1,para2)
六 awk的模式：
awk 'program' input-file1 input-file2 ...
其中的program为:
pattern { action }
pattern { action }
...
6.1 常见的模式类型：
1、Regexp 正则表达式，格式为/regular expression/
2、expresssion： 表达式，其值非0或为非空字符时满足条件，如：$1 ~ /foo/ 或 $1 == "magedu"，用运算符~(匹配)和!~(不匹配)。
3、Ranges 指定的匹配范围，格式为pat1,pat2
4、BEGIN/END 特殊模式，仅在awk命令执行前运行一次或结束前运行一次
5、Empty(空模式) 匹配任意输入行；
6.2 常见的Action
1、Expressions 表达式
2、Control statements 控制语句
3、Compound statements 组合语句
4、Input statements 输入语句
5、Output statements 输出语句
七 控制语句：
7.1 if-else
语法：if (condition) {then-body} else {[ else-body ]}
awk -v num1=11 -v num2=22 'BEGIN{if (num1>num2) {print "max="num1} else {print "max="num2}}'
awk -F: '{if ($1=="root") {printf "%-15s: %s\n", $1,"Admin";} else {printf "%-15s: %s\n", $1, "Common User"}}' /etc/passwd
7.2 while
语法： while (condition){statement1; statment2; ...}
awk -F: '{i=1;while (i<=3) {print $i;i++}}' /etc/passwd
awk -F: '{i=1;while (i<=3) {printf "%10s",$i;i++};printf "\n"}' /etc/passwd
awk -F: '{i=1;while (i<=NF) { if (length($i)>=4) {print $i}; i++ }}' /etc/passwd
awk '{i=1;while (i<=NF) {if ($i>=10000) {print $i};i++}}' hello.txt
hello.txt文件的内容为一堆随机数。
7.3 do-while 至少执行一次循环体，不管条件满足与否
语法： do {statement1, statement2, ...} while (condition)
awk -F: '{i=1;do {print $i;i++}while(i<=3)}' /etc/passwd
awk -F: '{i=4;do {print $i;i--}while(i>4)}' /etc/passwd
7.4 for
语法： for ( variable assignment; condition; iteration process) { statement1, statement2, ...}
awk -F: '{for(i=1;i<=3;i++) print $i}' /etc/passwd
awk -F: '{for(i=1;i<=NF;i++) { if (length($i)>=4) {print $i}}}' /etc/passwd
for循环还可以用来遍历数组元素：
语法： for (i in array) {statement1, statement2, ...}
统计/etc/passwd中排查空行后，每种shell的行数
awk -F: '$NF!~/^$/{BASH[$NF]++}END{for(A in BASH){printf "%15s:%i\n",A,BASH[A]}}' /etc/passwd
统计每种链接状态的链接数
netstat -tn | awk '/^tcp/{state[$NF]++}END{for (s in state) {printf "%15s %d\n",s,state[s]}}'
记录WEB访问IP数
awk '!/^$/{access[$1]++}END{for (i in access) {printf "%s:%d\n",i,access[i]}}' /var/log/httpd/access_log
每个资源被访问的次数
awk '/GET/{access[$7]++}END{for (i in access) {printf "%s:%d\n",i,access[i]}}' /var/log/httpd/access_log
awk '/GET/{split($7,s,"?")access[s[1]]++}END{for (i in access) {printf "%s:%d\n",i,access[i]}}' /var/log/httpd/access_log
统计各状态码的次数
awk '!/^$/{access[$9]++}END{for (i in access) {printf "%s:%d\n",i,access[i]}}' /var/log/httpd/access_log
7.5 case（测试发现centos6无法执行，centos7可以执行）
语法：switch (expression) { case VALUE or /REGEXP/: statement1, statement2,... default: statement1, ...}
awk '!/^#|^$/{switch($3) {case "xfs": print "i am xfs"; break;case "ext4": print "i am ext4";break;default: print "unkown";break}}' /etc/fstab
7.6 break 和 continue
break 结束整个循环
continue 提前结束本次循环而直接进入下一轮循环
awk 'BEGIN{i=1;while (i<=10) {if (i==6) {break}; print i;i++;}}'
7.7 next
提前结束对本行文本的处理，并接着处理下一行；例如，下面的命令将显示其ID号为奇数的用户：
# awk -F: '{if($3%2==0) next;print $1,$3}' /etc/passwd
八 awk中使用数组
8.1 数组
要遍历数组中的每一个元素，需要使用如下的特殊结构：
for (var in array) { statement1, ... }
其中，var用于引用数组下标，而不是元素值；
8.2 删除数组变量
从关系数组中删除数组索引需要使用delete命令。使用格式为：
delete array[index]
九、awk的内置函数
split(string, array [, fieldsep [, seps ] ])
功能：将string表示的字符串以fieldsep为分隔符进行分隔，并将分隔后的结果保存至array为名的数组中；数组下标为从1开始的序列；
记录IP访问次数
# netstat -ant | awk '/:80\>/{split($5,clients,":");IP[clients[4]]++}END{for(i in IP){print IP[i],i}}' | sort -rn | head -50
使用率超过20%的挂载点
# df -lh | awk '!/^File/{split($5,percent,"%");if(percent[1]>=5){print $1}}'
length([string])
功能：返回string字符串中字符的个数；
awk -F: '{for(i=1;i<=NF;i++) { if (length($i)>=4) {print $i}}}' /etc/passwd
substr(string, start [, length])
功能：取string字符串中的子串，从start开始，取length个；start从1开始计数；
system(command)
功能：执行系统command并将结果返回至awk命令
systime()
功能：取系统当前时间
tolower(s)
功能：将s中的所有字母转为小写
toupper(s)
功能：将s中的所有字母转为大写
十、用户自定义函数
自定义函数使用function关键字。格式如下：
function F_NAME([variable])
{
statements
}
函数还可以使用return语句返回值，格式为“return value”。