第十九课 代币锁仓后逐步释放的ERC20智能合约实践

版权声明：如需转载，请私信联系作者。 https://blog.csdn.net/wangdenghui2005/article/details/82865665

#1，摘要
【本文目标】
通过本文学习，可以实现区块链私募，基金会员工期权(代币)激励时锁仓一定时间，逐步释放的方法。

【前置条件】
1）已经完成了一个ERC20的代币，本文以作者接触的CLB为样例。
2） 懂得在REMIX调试SOLIDITY语言，不熟悉的参考文章《第十课 Solidity语言编辑器REMIX指导大全》。

#2，需求实现描述
一般区块链项目在私募或者员工沟通时，都会明确代币发放的政策，一般来说都会要求项目上线后锁仓多久，分几年释放。如果通过合同的方式来人工操作，一个是实现比较麻烦或者存在不可控性，另一方面也存在无法取信私募机构或者员工的情况。
那么专业的团队会选择通过智能合约来实现，这是更可信、公开、且不可串改的最佳方式。
这个实现概括讲包括3步：
1）发布ERC20代币智能合约
2）配置锁仓合约参数, 发布锁仓的智能合约
3）把要锁仓的ERC20代币转入锁仓智能合约
其中锁仓智能合约的文章极少，很多人不知怎么实现，辉哥来做个分享。

#3，锁仓智能合约分析
锁仓智能合约核心代码：

/**
 * @title TokenVesting
 * @dev A token holder contract that can release its token balance gradually like a
 * typical vesting scheme, with a cliff and vesting period. Optionally revocable by the
 * owner.
 */
contract TokenVesting is Ownable {
  using SafeMath for uint256;
  using SafeERC20 for Colorbay;

  event Released(uint256 amount);
  event Revoked();

  // beneficiary of tokens after they are released
  address public beneficiary;

  uint256 public cliff;
  uint256 public start;
  uint256 public duration;

  bool public revocable;

  mapping (address => uint256) public released;
  mapping (address => bool) public revoked;

  /**
   * @dev Creates a vesting contract that vests its balance of any ERC20 token to the
   * _beneficiary, gradually in a linear fashion until _start + _duration. By then all
   * of the balance will have vested.
   * @param _beneficiary address of the beneficiary to whom vested tokens are transferred
   * @param _cliff duration in seconds of the cliff in which tokens will begin to vest
   * @param _start the time (as Unix time) at which point vesting starts
   * @param _duration duration in seconds of the period in which the tokens will vest
   * @param _revocable whether the vesting is revocable or not
   */
  constructor(
    address _beneficiary,
    uint256 _start,
    uint256 _cliff,
    uint256 _duration,
    bool _revocable
  )
    public
  {
    require(_beneficiary != address(0));
    require(_cliff <= _duration);

    beneficiary = _beneficiary;
    revocable = _revocable;
    duration = _duration;
    cliff = _start.add(_cliff);
    start = _start;
  }

  /**
   * @notice Transfers vested tokens to beneficiary.
   * @param _token Colorbay token which is being vested
   */
  function release(Colorbay _token) public {
    uint256 unreleased = releasableAmount(_token);

    require(unreleased > 0);

    released[_token] = released[_token].add(unreleased);

    _token.safeTransfer(beneficiary, unreleased);

    emit Released(unreleased);
  }

  /**
   * @notice Allows the owner to revoke the vesting. Tokens already vested
   * remain in the contract, the rest are returned to the owner.
   * @param _token ERC20 token which is being vested
   */
  function revoke(Colorbay _token) public onlyOwner {
    require(revocable);
    require(!revoked[_token]);

    uint256 balance = _token.balanceOf(address(this));

    uint256 unreleased = releasableAmount(_token);
    uint256 refund = balance.sub(unreleased);

    revoked[_token] = true;

    _token.safeTransfer(owner, refund);

    emit Revoked();
  }

  /**
   * @dev Calculates the amount that has already vested but hasn't been released yet.
   * @param _token Colorbay token which is being vested
   */
  function releasableAmount(Colorbay _token) public view returns (uint256) {
    return vestedAmount(_token).sub(released[_token]);
  }

  /**
   * @dev Calculates the amount that has already vested.
   * @param _token ERC20 token which is being vested
   */
  function vestedAmount(Colorbay _token) public view returns (uint256) {
    uint256 currentBalance = _token.balanceOf(this);
    uint256 totalBalance = currentBalance.add(released[_token]);
    
    if (block.timestamp < cliff) {
      return 0;
    } else if (block.timestamp >= start.add(duration) || revoked[_token]) {
      return totalBalance;
    } else {
      return totalBalance.mul(block.timestamp.sub(start)).div(duration);
    }
  }
}

函数说明：
1，锁仓合约初始化函数constructor(…)，包含5个参数：

• address _beneficiary：接受通证投放的收益账户；
• uint256 _start： 起始时间（Unix time），提示从什么时刻开始计时；
• uint256 _cliff： 单位为秒（s），断崖时间，例如“锁仓4年，1年之后一次性解冻25%”中的1年
• uint256 _duration： 单位为秒（s），持续锁仓时间，例如“锁仓4年，1年之后一次性解冻25%”中的4年；
• bool _revocable： 是否可回收 （例如公司给了员工张三 10K 代币锁仓4年，张三在工作一年的时候离职了，剩余的部分公司是否可回收）
  举例来说明：
  如果 _cliff=半年 ，_duration=1年 具体解冻情况如下：
  Month 1: I get 0 tokens
  Month 2: I get 0 tokens
  Month 3: I get 0 tokens
  Month 4: I get 0 tokens
  Month 5: I get 0 tokens
  Month 6: I get 0 tokens — End of cliff
  Month 7: I get 700 tokens (7/12th)
  Month 8: I get 100 tokens (8/12th)
  Month 9: I get 100 tokens (9/12th)
  Month 10: I get 100 tokens (10/12th)
  Month 11: I get 100 tokens (11/12th)
  Month 12: I get 100 tokens (12/12th)

2，期权代币释放函数release(…)，包含1个参数：

• Colorbay _token：_token为CLB代币的实例参数，时间到后通过该函数释放给对应的收益账户；

3，期权代币回收函数revoke(…)，包含1个参数：

• Colorbay _token：_token为CLB代币的实例参数，把未释放的代币打回给之前的分配账户池；

完整的代码和CLB通证的调用函数，辉哥存放到知识星球，欢迎加入下载。

#3, 测试用例验证
1] 管理员账号发布一个ERC20的ColorBay代币合约

• 管理员地址：
  0xca35b7d915458ef540ade6068dfe2f44e8fa733c
• 代币合约信息如下：
  (1) decimals = 18; (2) totalSupply() = 10亿； (3) symbol = CLB (4) paused = false
  (5) owner = 0xca35b7d915458ef540ade6068dfe2f44e8fa733c
  (6) contract address = 0x692a70d2e424a56d2c6c27aa97d1a86395877b3a

2] 管理员账号转发500万给员工激励专用账号用于期权激励专用

• 管理员地址：
  0xca35b7d915458ef540ade6068dfe2f44e8fa733c
• 员工激励专用账号地址：
  0x14723a09acff6d2a60dcdf7aa4aff308fddc160c
• 转账操作：(记得去除500万后面的",")
  transfer(“0x14723a09acff6d2a60dcdf7aa4aff308fddc160c”, “5000000,000000000000000000”)
  【结果验证】
  balanceOf(“0x14723a09acff6d2a60dcdf7aa4aff308fddc160c”)
  检查确认余额为500万CLB。

3] 当前账号切换到员工激励专用账号下创建期权激励计划

• 场景假设：
  激励计划起始时间为[2018.08.06 20:25]，2分钟内不得释放，持续5分钟(300s),支持回收未释放的期权
• 员工激励专用账号地址：
  0x14723a09acff6d2a60dcdf7aa4aff308fddc160c
• 被员工李四的私人收益账号地址：
  0x4b0897b0513fdc7c541b6d9d7e929c4e5364d2db
• 调用函数： constructor(“0x4b0897b0513fdc7c541b6d9d7e929c4e5364d2db”, “1533558300”, “120”, “300”, true)
  【说明】如何获得准确的起始时间，可用站长工具输入具体时间来转换。
• 期权激励智能合约实例创建成功信息如下：
  (1) contract address = 0x0fdf4894a3b7c5a101686829063be52ad45bcfb7

4] 在CLB合约下，把CLB通证打给期权激励智能合约地址

• 切换到员工激励专用账号
  0x14723a09acff6d2a60dcdf7aa4aff308fddc160c
• 执行转账操作，（记得去除100万后面的","）
  transfer(“0x0fdf4894a3b7c5a101686829063be52ad45bcfb7”, “1000000,000000000000000000”)
• 结果
  balanceOf(“0x0fdf4894a3b7c5a101686829063be52ad45bcfb7”) 检查确认余额为100万，表示CLB代币已经转给期权激励智能合约了。

5] [2018.08.06 17:31] 5分钟(300s)后测试分配期权

• 执行期权是否操作
  release(“0x692a70d2e424a56d2c6c27aa97d1a86395877b3a”)
• 切换到CLB合约下，查询李四私人账号
  balanceOf(“0x4b0897b0513fdc7c541b6d9d7e929c4e5364d2db”) 检查确认余额为100万，转账成功。
  

6] 离职员工激励计划实施

• 场景假设
  当前账号切换到员工激励专用账号下创建期权激励计划，假定给员工王五做的激励，起始时间为[2018.08.06 21:00]，2分钟内不得释放，持续5分钟(300s),支持回收期权。王五在4分钟的时候离职，公司收回未激励代币，打回到员工激励专用账号下。

• 员工激励专用账号：
  0x14723a09acff6d2a60dcdf7aa4aff308fddc160c

• 被员工王五私人收益账号：
  0x583031d1113ad414f02576bd6afabfb302140225

• 执行操作： constructor(“0x583031d1113ad414f02576bd6afabfb302140225”, “1533560400”, “120”, “300”, true)

• 期权激励智能合约信息如下：
  contract address = 0x15e08fa9fe3e3aa3607ac57a29f92b5d8cb154a2

7] 在CLB合约下，通证打给期权激励智能合约地址

• 切换到员工激励专用账号，在CLB合约下操作
  0x14723a09acff6d2a60dcdf7aa4aff308fddc160c
• 王五期权激励智能合约实例地址：
  0x15e08fa9fe3e3aa3607ac57a29f92b5d8cb154a2
• 具体操作（记得去除100万后面的","）
  transfer(“0x15e08fa9fe3e3aa3607ac57a29f92b5d8cb154a2”, “1000000,000000000000000000”)
• 查询王五期权激励智能合约的账户余额：
  balanceOf(“0x15e08fa9fe3e3aa3607ac57a29f92b5d8cb154a2”) 检查确认余额为100万
• 查询员工期权激励智能合约的账户余额：
  balanceOf(“0x14723a09acff6d2a60dcdf7aa4aff308fddc160c”)
  检查确认余额为300万

8] [2018.08.06 21:03] 3分钟(180s)后测试分配期权

• 2分钟内操作release均会失败回滚。21:03操作释放函数：
  release(“0x692a70d2e424a56d2c6c27aa97d1a86395877b3a”)
• 切换到CLB合约下，查询王五私人账号
  balanceOf(“0x583031d1113ad414f02576bd6afabfb302140225”) 检查有76万代币释放到王五收益账户。
  

9] [2018.08.06 21:05] 4分钟(240s)后，李四离职，收回分配期权
revoke(“0x692a70d2e424a56d2c6c27aa97d1a86395877b3a”)

• 切换到CLB合约下，查询李四私人账号
  balanceOf(“0x583031d1113ad414f02576bd6afabfb302140225”) 检查有76万代币在王五收益账户，没有增加。
  

• 查询员工专用账户余额
  balanceOf(“0x14723a09acff6d2a60dcdf7aa4aff308fddc160c”)
  发现王五剩余未释放的额度全部返回到员工专用账号了。

#4， 商用实现需求
辉哥给了一个命题需求，看看谁能把这个需求实现。除了功能，要提供网页查询页面，用户输入以太坊地址，可以查到对应账户的期权代币总额，已释放额度，未释放额度。

某项目方发布10亿的代币总额，其中：
1] 机构方私募为 1.5 亿枚， 上交易所后私募锁仓三个月，之后逐月释放 20%；
2] 基金会核心运作团队持有 2 亿枚， 锁定一年， 两年内逐步释放；
3] 社区建设 1 亿枚， 海外社区核心团队， 锁定一年，两年内逐步释放；

转化为具体的时间点动作为：
1] 私募总额1.5亿枚，2018.09.01上交易所，私募锁仓三个月到2018.12.01到期，之后逐月释放情况
[2019.01.01 - 20%, 3000万枚; 2019.02.01 - 20%, 3000万枚; 2019.03.01 - 20%, 3000万枚; 2019.04.01 20%, 3000万枚; 2019.05.01 20%, 3000万枚; ]
2] 基金会核心运作团队 2亿枚,2018.09.01上交易所，锁定一年到2019.09.01， 两年内按月逐步释放；
[2019.10.01 - 2亿1/24, 约833万枚; …; 2020.10.01 - 2亿1/24, 约833万枚;]
3] 海外社区核心团队 1 亿枚，2018.09.01上交易所，锁定一年到2019.09.01，两年内逐步释放；
[2019.10.01 - 1亿1/24, 约416万枚; …; 2020.10.01 - 1亿1/24, 约416万枚;]

我们已完成该商用合约的编码，取得了链安科技的合约审计验收。有需要合作的可勾搭下下。

#5, 参考
1）关于ERC20代币的锁仓
2） 授权和释放合约
3） 定时释放合约