版权声明:本文为博主原创文章,未经博主允许不得转载,如有技术需要联系[email protected]! https://blog.csdn.net/harrison2010/article/details/80457598
目的
学习智能合约的开发以及使用流程
期望
- A发起智能合约,设定选择项目(比如 1,2,3,4)
- A设定那些人可以进行投票,先对可以进行投票的人授权
- 已经被授权的人可以投票,没被授权的人投票无效
- 计算最终那个选项投票数最多
合约代码
pragma solidity ^0.4.16;
/// @title Voting with delegation.
contract Ballot {
// This declares a new complex type which will
// be used for variables later.
// It will represent a single voter.
struct Voter {
uint weight; // weight is accumulated by delegation
bool voted; // if true, that person already voted
address delegate; // person delegated to
uint vote; // index of the voted proposal
}
// This is a type for a single proposal.
struct Proposal {
bytes32 name; // short name (up to 32 bytes)
uint voteCount; // number of accumulated votes
}
address public chairperson;
// This declares a state variable that
// stores a `Voter` struct for each possible address.
mapping(address => Voter) public voters;
// A dynamically-sized array of `Proposal` structs.
Proposal[] public proposals;
/// Create a new ballot to choose one of `proposalNames`.
function Ballot(bytes32[] proposalNames) public {
chairperson = msg.sender;
voters[chairperson].weight = 1;
// For each of the provided proposal names,
// create a new proposal object and add it
// to the end of the array.
for (uint i = 0; i < proposalNames.length; i++) {
// `Proposal({...})` creates a temporary
// Proposal object and `proposals.push(...)`
// appends it to the end of `proposals`.
proposals.push(Proposal({
name: proposalNames[i],
voteCount: 0
}));
}
}
// Give `voter` the right to vote on this ballot.
// May only be called by `chairperson`.
function giveRightToVote(address voter) public {
// If the argument of `require` evaluates to `false`,
// it terminates and reverts all changes to
// the state and to Ether balances. It is often
// a good idea to use this if functions are
// called incorrectly. But watch out, this
// will currently also consume all provided gas
// (this is planned to change in the future).
require(
(msg.sender == chairperson) &&
!voters[voter].voted &&
(voters[voter].weight == 0)
);
voters[voter].weight = 1;
}
/// Delegate your vote to the voter `to`.
function delegate(address to) public {
// assigns reference
Voter storage sender = voters[msg.sender];
require(!sender.voted);
// Self-delegation is not allowed.
require(to != msg.sender);
// Forward the delegation as long as
// `to` also delegated.
// In general, such loops are very dangerous,
// because if they run too long, they might
// need more gas than is available in a block.
// In this case, the delegation will not be executed,
// but in other situations, such loops might
// cause a contract to get "stuck" completely.
while (voters[to].delegate != address(0)) {
to = voters[to].delegate;
// We found a loop in the delegation, not allowed.
require(to != msg.sender);
}
// Since `sender` is a reference, this
// modifies `voters[msg.sender].voted`
sender.voted = true;
sender.delegate = to;
Voter storage delegate_ = voters[to];
if (delegate_.voted) {
// If the delegate already voted,
// directly add to the number of votes
proposals[delegate_.vote].voteCount += sender.weight;
} else {
// If the delegate did not vote yet,
// add to her weight.
delegate_.weight += sender.weight;
}
}
/// Give your vote (including votes delegated to you)
/// to proposal `proposals[proposal].name`.
function vote(uint proposal) public {
Voter storage sender = voters[msg.sender];
require(!sender.voted);
require(sender.weight == 1);
sender.voted = true;
sender.vote = proposal;
// If `proposal` is out of the range of the array,
// this will throw automatically and revert all
// changes.
proposals[proposal].voteCount += sender.weight;
}
/// @dev Computes the winning proposal taking all
/// previous votes into account.
function winningProposal() public view
returns (uint winningProposal_)
{
uint winningVoteCount = 0;
for (uint p = 0; p < proposals.length; p++) {
if (proposals[p].voteCount > winningVoteCount) {
winningVoteCount = proposals[p].voteCount;
winningProposal_ = p;
}
}
}
// Calls winningProposal() function to get the index
// of the winner contained in the proposals array and then
// returns the name of the winner
function winnerName() public view
returns (bytes32 winnerName_)
{
winnerName_ = proposals[winningProposal()].name;
}
}
使用流程-发布
首先你要搭建一个私链的环境(当然如果你是土豪,可以直接使用公链),具体怎么搭建可以参考
搭建以太坊私链
在钱包选择contracts(合同),点击deploy new contract(发布一个新的合同)
第二步,把上面的代码复制其中,等待编译后.右面选择函数名字,以及设置投票选择的分类(这里我用1,2,3,4代替)
然后发布
等待一个块产生后(在钱包主页面查看),合同就生成了,如下.
使用流程-授权
用刚才创建合同的账号,给让参与投票的账号授权,点击进入合同.
选择give right to vote.填写参与者的地址.
使用流程-投票
选择投票函数,填写要投票的选项(这里是从0开始的计算.所以0表示上面投票给了1选项.当然上面的选择可以不用数字比如 水果 [苹果,西红柿,西瓜],那么0就表示苹果,1表示西红柿. 而且这里的值不在数字的范围内是会报错的.)
使用流程-查看结果
1.可以根据选项查看投票的数量
2.查看那个选项得票率最高
3.根据用户查看他投那个选项的票,以及是否授权等
关联的所有交易查看
以上参考网络上的一个只能合约做了修改(修复了之前那个人的错误),还加入了自己的解释. 里面还包含了可以委托没有讲.
个人总结:
- 其实智能合约一定是基于交易的,而且里面除了自己的变量设定之外.只能调用连上的部分东西
- 虽然是图灵完备,但是功能有限
- 每次交易数据状态完全存储,感觉这个会是智能合约的痛
4.去中心化以及永不丢失的优点,必然会让很多缺点暴露无疑.