arm汇编指令笔记

.equ 通俗点说定义常量 .equ SDRAM_BASE, 0x30000000

例子 mov r1, #MEM_CTL_BASE
2..text .global 是arm-gcc编译器的关键词。
.text 指定了后续编译出来的内容放在代码段【可执行】;

.global 告诉编译器后续跟的是一个全局可见的名字【可能是变量，也可以是函数名】；

3.bl指令。 BL在跳转之前，将其下一条指令的地址拷贝到R14（LR,链接寄存器）。由于BL指令保存了下条指令的地址，因此使用指令“MOV PC ,LR”即可实现子程序的返回。

_start:
    bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启
    bl  memsetup                        @ 设置存储控制器

disable_watch_dog:
    mov r1,     #0x53000000
    mov r2,     #0x0
    str r2,     [r1]
mov pc,     lr      @ 返回继续执行bl下面的语句

4.ldr指令（装载）有等号是把地址给前面，没有等号是值

ldr sp, =0x34000000     地址给sp
ldr r4, [r2]    数据或者指令内容赋值给r4 . 
ldr  r4, [r2],#4    r2，地址里的内容，给r4，然后r2的值+4

5.str指令 (读取）
STR R0，[R1]，＃8 ；将R0中的字数据写入以R1为地址的存储器中，并将R1的值＋8写入R1。
STR R0，[R1，＃8] ；将R0中的字数据写入以R1＋8为地址的存储器中。”
str r1, [r0] ；将r1寄存器的值，传送到地址值为r0的（存储器）内存中

6.cmp指令
CMP 允许把一个寄存器的内容跟另一个寄存器的内容或立即值进行比较。做减法比较
7.bne 非零则跳转，若zero==1，跳转到led_blink处执行；若zero==0，则继续执行下一步指令
cmp r1, r3
bne 1b @ 非零则跳转，若zero==1，跳转到l标号出处执行；若zero==0，则继续执行下一步
mov pc, lr @ 返回

.align4 .align num num是2的n次方。为了对齐地址的。也就是地址4k对齐

———————–来看个例子———————————————————————————
存储控制器的实验的启动文件，初始化存储控制器还有拷贝片内ram到sdram

@*************************************************************************
@ File：head.S
@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行
@*************************************************************************       

.equ        MEM_CTL_BASE,       0x48000000
.equ        SDRAM_BASE,         0x30000000

.text
.global _start
_start:
    bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启
    bl  memsetup                        @ 设置存储控制器
    bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中
    ldr pc, =on_sdram                   @ 跳到SDRAM中继续执行
on_sdram:
    ldr sp, =0x34000000                 @ 设置堆栈
    bl  main
halt_loop:
    b   halt_loop

disable_watch_dog:
    @ 往WATCHDOG寄存器写0即可
    mov r1,     #0x53000000
    mov r2,     #0x0
    str r2,     [r1]
    mov pc,     lr      @ 返回

copy_steppingstone_to_sdram:
    @ 将Steppingstone的4K数据全部复制到SDRAM中去
    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000

    mov r1, #0
    ldr r2, =SDRAM_BASE
    mov r3, #4*1024
1:  
    ldr r4, [r1],#4     @ 从Steppingstone读取4字节的数据，并让源地址加4
    str r4, [r2],#4     @ 将此4字节的数据复制到SDRAM中，并让目地地址加4
    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？
    bne 1b              @ 若没有复制完，继续    非零则跳转，若zero==1，跳转到led_blink处执行；若zero==0，则继续执行下一步指令
    mov pc,     lr      @ 返回


    @这两行赋值。  
    @  ldr r4,     [r2], #4            @ 读取设置值，并让r2加4
    @str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4
    @ 明确目的是为了初始化寄存器，就是往里面写值。 用循环13次
    @ ldr  是 把要写的值装进r4 .  str是把r4 的值写入 r1为地址的寄存器。  两者的+4都是r2 和r1里面的值+4.
memsetup:
    @ 设置存储控制器以便使用SDRAM等外设

    mov r1,     #MEM_CTL_BASE       @ 存储控制器的13个寄存器的开始地址
    adrl    r2, mem_cfg_val         @ 这13个值的起始存储地址
    add r3,     r1, #52             @ 13*4 = 54
1:  
    ldr r4,     [r2], #4            @ 读取设置值，并让r2加4
    str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4
    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器
    bne 1b                          @ 若没有写成，继续
    mov pc,     lr                  @ 返回


.align 4
mem_cfg_val:
    @ 存储控制器13个寄存器的设置值
    .long   0x22011110      @ BWSCON
    .long   0x00000700      @ BANKCON0
    .long   0x00000700      @ BANKCON1
    .long   0x00000700      @ BANKCON2
    .long   0x00000700      @ BANKCON3  
    .long   0x00000700      @ BANKCON4
    .long   0x00000700      @ BANKCON5
    .long   0x00018005      @ BANKCON6
    .long   0x00018005      @ BANKCON7
    .long   0x008C07A3      @ REFRESH
    .long   0x000000B1      @ BANKSIZE
    .long   0x00000030      @ MRSRB6
    .long   0x00000030      @ MRSRB7

8.msr 类似ldr 第二个参数跟寄存器或者立即数，装到寄存器里面

    MSR CPSR，R0    @传送R0的内容到CPSR

猜你喜欢