LCD1602汇编代码

仿真图片

汇编代码

main.asm

$INCLUDE(LCD1602.INC)
ORG		0000H
LJMP	MAIN
ORG		0100H
MAIN:
	MOV		SP,	#60H
	MOV		LCD_DAT,	#'A'
	LCALL	LCD_W_DATA
	MOV		LCD_DAT,	#'B'
	LCALL	LCD_W_DATA
	LCALL	LCD_INIT
END
	

LCD1602.asm

;程序名称：	LCD1602.asm
;程序说明：	1602汇编程序，51单片机汇编程序，仅需修改引脚定义即可。晶振大小12M，
;			程序测试完全正确。内部包含写数据、写命令（包括读忙和不读忙）、初始化等子函数。
;			调用时先给LCD_DAT赋值，给出需要写入的数据或命令，然后调用。
;			eg:	写数据：	MOV		LCD_DAT,	#'A'	;30H为LCD_DAT
;						LCALL	LCD_W_DATA
;				写命令：	MOV		LCD_DAT,	#38H	;30H为LCD_DAT
;						LCALL	LCD_W_CMD			;(或者LCD_CMD)
;以下是变量及函数的声明
PUBLIC LCD_R_DATA
PUBLIC LCD_W_DATA
PUBLIC LCD_W_CMD
PUBLIC LCD_CMD
PUBLIC LCD_INIT
PUBLIC LCD_DAT
PUBLIC LCD_FLAG
PUBLIC LCD_Line_BIT
;***************************************************
;定义程序区块，编译时动态分配程序地址，此段代码可以不要
	_LCD1602_ASM SEGMENT CODE
	RSEG	_LCD1602_ASM
;***************************************************
LCD_RS			BIT		P2.5	 	;1602数据命令选择端口
LCD_RW			BIT		P2.6	 	;1602读写选择端口
LCD_EN			BIT		P2.7	 	;1602使能端口
LCD_DATA		EQU		P0		 	;1602数据端口

;变量声明区
LCD_ALL_FLAG	DATA		20H		 		;标志位
LCD_FLAG		BIT			LCD_ALL_FLAG.0	;1602读忙标志位
LCD_Line_BIT	BIT			LCD_ALL_FLAG.1	;换行标志位
LCD_DAT			DATA		21H		 		;1602数据命令字	
LED_DELAYED		DATA		22H		 		;延时字
/*****************************************
1602读命令函数，高位存至LCD_LAG中
*****************************************/
LCD_R_DATA:
			MOV		LCD_DATA,#0FFH
LCD_BUSY:	CLR		LCD_RS
			SETB		LCD_RW
			NOP
			SETB		LCD_EN
			NOP
			MOV		Acc,LCD_DATA
			MOV		C,Acc.7
			MOV		LCD_FLAG,C
			CLR		LCD_EN
			NOP
			JB		LCD_FLAG,LCD_BUSY	
			RET			

/*****************************************
1602写数据函数，数据存在LCD_DAT
*****************************************/
LCD_W_DATA:
			LCALL	LCD_R_DATA
			SETB		LCD_RS
			CLR		LCD_RW
			NOP			
			MOV		LCD_DATA,LCD_DAT
			SETB		LCD_EN
			NOP
			CLR		LCD_EN
			RET
/*****************************************
1602写命令函数，命令存在LCD_DAT,检测忙信号
*****************************************/			
LCD_W_CMD:
			LCALL	LCD_R_DATA
			CLR		LCD_RS
			CLR		LCD_RW
			NOP		
			MOV		LCD_DATA,LCD_DAT
			SETB		LCD_EN
			NOP
			CLR		LCD_EN
			RET
/*****************************************
1602写命令函数，命令存在LCD_DAT，不检测忙信号
*****************************************/			
LCD_CMD:
			CLR		LCD_RS
			CLR		LCD_RW
			NOP		
			MOV		LCD_DATA,LCD_DAT
			SETB		LCD_EN
			NOP
			CLR		LCD_EN
			RET
/*****************************************
1602初始化函数
*****************************************/
LCD_INIT:
			CLR		LCD_Line_BIT		;第一行
			MOV		LED_DELAYED,#30
			LCALL	LCD_DELAY_MS
			MOV		LCD_DAT,#38H	//设置显示模式
			LCALL	LCD_CMD
			MOV		LED_DELAYED,#10
			LCALL	LCD_DELAY_MS		    
			MOV		LCD_DAT,#38H
			LCALL	LCD_CMD
			MOV		LED_DELAYED,#10
			LCALL	LCD_DELAY_MS
			MOV		LCD_DAT,#38H
			LCALL	LCD_CMD
			MOV		LED_DELAYED,#10
			LCALL	LCD_DELAY_MS
			MOV		LCD_DAT,#038H	//设置显示模式
			LCALL	LCD_W_CMD
			MOV		LCD_DAT,#08H	//显示开
			LCALL	LCD_W_CMD
			MOV		LCD_DAT,#01H	//清屏
			LCALL	LCD_W_CMD
			MOV		LCD_DAT,#06H	//写第一个指针+1
			LCALL	LCD_W_CMD
			MOV		LCD_DAT,#0EH	//开显示显示光标，光标不闪烁
			LCALL	LCD_W_CMD
			RET
/*****************************************
延时函数，延时时间为LED_DELAYED*0.5毫秒 0~100毫秒的延时
*****************************************/			
LCD_DELAY_MS:	
			MOV		R7,LED_DELAYED
D1:			MOV		R6,#0F8H
D2:			DJNZ	R6,D2	
			DJNZ	R7,D1
			RET
/*****************************************
延时函数，延时时间为LED_DELAYED*2微秒	 0~500微秒的延时
*****************************************/			
LED_DELAY_US:
			MOV		R7,A	
DU1:		
			DJNZ	R7,DU1
			RET
END

LCD1602.inc

;外部函数的声明
EXTRN CODE(LCD_R_DATA)
EXTRN CODE(LCD_W_DATA)
EXTRN CODE(LCD_W_CMD)
EXTRN CODE(LCD_CMD)
EXTRN CODE(LCD_INIT)
EXTRN DATA(LCD_DAT)
EXTRN BIT(LCD_FLAG)
EXTRN BIT(LCD_Line_BIT)