Lingo软件入门

Lingo入门

目录

1.集

2.数据

3.函数

---

1.集

定义一个原始集，用下面的语法：

sets：
setname[/member_list/][:attribute_list];
endsets

(1)Setname是你选择的来标记集的名字；
(2)Member_list是集成员列表
分为显式和隐式，一般常用隐式：

集 ←→ 结构体
集成员 ←→ 结构体的域
集属性 ←→ 结构体实例

–

sets:
  product/A B/;
  machine/M N/;
  week/1..2/;
  allowed(product,machine,week):x;
endsets

LINGO生成了三个父集的所有组合共八组作为allowed集的成员。
或者：

sets:
allowed(product,machine,week)/A M 1,A N 2,B N 1/：x;

endsets

总的来说，LINGO可识别的集只有两种类型：原始集和派生集。

原始集是基本的对象，不能再被拆分成更小的组分。原始集可以由显式罗列和隐式罗列两种方式来定义。当用显式罗列方式时，需在集成员列表中逐个输入每个成员。当用隐式罗列方式时，只需在集成员列表中输入首成员和末成员，而中间的成员由LINGO产生。
另一方面，派生集是由其它的集来创建。这些集被称为该派生集的父集（原始集或其它的派生集）。一个派生集既可以是稀疏的，也可以是稠密的。稠密集包含了父集成员的所有组合（有时也称为父集的笛卡尔乘积）。稀疏集仅包含了父集的笛卡尔乘积的一个子集，可通过显式罗列和成员资格过滤器这两种方式来定义。显式罗列方法就是逐个罗列稀疏集的成员。成员资格过滤器方法通过使用稀疏集成员必须满足的逻辑条件从稠密集成员中过滤出稀疏集的成员。不同集类型的关系见下图。(allow就是派生集)

---

2.数据部分和初始部分

数据部分以关键字“data:”开始，以关键字“enddata”结束。在这里，可以指定集成员、集的属性。

(1)指定集成员、集的属性。

data：
object_list = value_list;

enddata

对象列（object_list）包含要指定值的属性名、要设置集成员的集名，用逗号或空格隔开。
数值列（value_list）包含要分配给对象列中的对象的值，用逗号或空格隔开。注意属性值的个数必须等于集成员的个数。

sets:
  set1/A,B,C/: X,Y;
endsets
data:
  X=1,2,3;
  Y=4,5,6;
enddata

其中，data也可以这么输入：

data:
  X,Y=1 4
      2 5
      3 6;
enddata

(2)参数；
在数据部分也可以指定一些标量变量（scalar variables）。当一个标量变量在数据部分确定时，称之为参数。
在某些情况，对于模型中的某些数据并不是定值。
在本该放数的地方输入一个问号（?）。

扫描二维码关注公众号，回复： 3320841 查看本文章

data:
  interest_rate,inflation_rate = .085  ?;
enddata

运行时会询问该变量的取值，这样就可以求解在范围内变量变化引起的模型变化。

(3)指定属性为1个值：

sets:
  days /MO,TU,WE,TH,FR,SA,SU/:needs;
endsets
data:
  needs = 20;
enddata

用20指定days集的所有成员的needs属性

sets:
  days /MO,TU,WE,TH,FR,SA,SU/:needs,cost;
endsets
data:
  needs cost = 20 100;
enddata

以上是对于多个属性的情形。

(4)未知数值
有时只想为一个集的部分成员的某个属性指定值，而让其余成员的该属性保持未知，以便让LINGO去求出它们的最优值。在数据声明中输入两个相连的逗号表示该位置对应的集成员的属性值未知。两个逗号间可以有空格

sets:
  years/1..5/: capacity;
endsets
data:
  capacity = ,34,20,,;
enddata

(5)模型的初始部分
一个初始部分以“init:”开始，以“endinit”结束。初始部分的初始声明规则和数据部分的数据声明规则相同。也就是说，我们可以在声明的左边同时初始化多个集属性，可以把集属性初始化为一个值，可以用问号实现实时数据处理，还可以用逗号指定未知数值。

init:
  X, Y = 0, .1;
endinit
Y=@log(X);
X^2+Y^2<=1;

---

3.函数

LINGO有9种类型的函数：

1． 基本运算符：包括算术运算符、逻辑运算符和关系运算符
(1)算术运算符的优先级由高到底为：
﹣（取反）高　
＾
*／
﹢﹣低　

---

(2)逻辑运算符
LINGO具有９种逻辑运算符：
#not#　 否定该操作数的逻辑值，＃not＃是一个一元运算符
#eq#　　若两个运算数相等，则为true；否则为flase
#ne# 若两个运算符不相等，则为true；否则为flase
#gt# 若左边的运算符严格大于右边的运算符，则为true；否则为flase
#ge#　 若左边的运算符大于或等于右边的运算符，则为true；否则为flase
#lt#　 若左边的运算符严格小于右边的运算符，则为true；否则为flase
#le#　 若左边的运算符小于或等于右边的运算符，则为true；否则为flase
#and#　 仅当两个参数都为true时，结果为true；否则为flase
#or# 仅当两个参数都为false时，结果为false；否则为true

---

(3)关系运算符
三种关系运算符：
“=”、“<=”和“>=”

---

(4)下面给出以上三类操作符的优先级：
高　#not# ﹣（取反）
　　＾
　　　﹡ ／
　﹢﹣
#eq# #ne# #gt# #ge# #lt# #le#
#and# #or#
低 <= = >=

---

2． * 数学函数*：三角函数和常规的数学函数

@abs(x)             返回x的绝对值
@sin(x)             返回x的正弦值，x采用弧度制
@cos(x)             返回x的余弦值
@tan(x)             返回x的正切值
@exp(x)             返回常数e的x次方
@log(x)             返回x的自然对数
@lgm(x)             返回x的gamma函数的自然对数
@sign(x)            如果x<0返回-1；否则，返回1
@floor(x)           返回x的整数部分。当x>=0时，返回不超过x的最大整数；当x<0时，返回不低于x的最大整数。
@smax(x1,x2,…,xn)  返回x1，x2，…，xn中的最大值
@smin(x1,x2,…,xn)  返回x1，x2，…，xn中的最小值

---

3． 金融函数：LINGO提供的两种金融函数
(1)

@fpa(I,n)
返回如下情形的净现值：单位时段利率为I，连续n个时段支付，
每个时段支付单位费用。若每个时段支付x单位的费用，则净现
值可用x乘以@fpa(I,n)算得。

返回如下情形的净现值：单位时段利率为I，连续n个时段支付，每个时段支付单位费用。若每个时段支付x单位的费用，则净现值可用x乘以@fpa(I,n)算得。例题如下：

50000 = x * @fpa(.0531,10);

(2)

@fpl(I,n)
单位时段利率为I，第n个时段支付单位费用 
输出为 （1+I）^(-n)

---

4． 概率函数：LINGO提供了大量概率相关的函数

1．@pbn(p,n,x)
二项分布的累积分布函数。当n和（或）x不是整数时，用线性插值法进行计算。
2．@pcx(n,x)
自由度为n的χ2分布的累积分布函数。
3．@peb(a,x)
当到达负荷为a，服务系统有x个服务器且允许无穷排队时的Erlang繁忙概率。
4．@pel(a,x)
当到达负荷为a，服务系统有x个服务器且不允许排队时的Erlang繁忙概率。
5．@pfd(n,d,x)
自由度为n和d的F分布的累积分布函数。
6．@pfs(a,x,c)
当负荷上限为a，顾客数为c，平行服务器数量为x时，有限源的Poisson服务系统的等待或返修顾客数的期望值。a是顾客数乘以平均服务时间，再除以平均返修时间。当c和（或）x不是整数时，采用线性插值进行计算。
7．@phg(pop,g,n,x)
超几何（Hypergeometric）分布的累积分布函数。pop表示产品总数，g是正品数。从所有产品中任意取出n（n≤pop）件。pop，g，n和x都可以是非整数，这时采用线性插值进行计算。
8．@ppl(a,x)
Poisson分布的线性损失函数，即返回max(0,z-x)的期望值，其中随机变量z服从均值为a的Poisson分布。
9．@pps(a,x)
均值为a的Poisson分布的累积分布函数。当x不是整数时，采用线性插值进行计算。
10．@psl(x)
单位正态线性损失函数，即返回max(0,z-x)的期望值，其中随机变量z服从标准正态分布。
11．@psn(x)
标准正态分布的累积分布函数。
12．@ptd(n,x)
自由度为n的t分布的累积分布函数。
13．@qrand(seed)
产生服从(0,1)区间的拟随机数。@qrand只允许在模型的数据部分使用，它将用拟随机数填满集属性。通常，声明一个m×n的二维表，m表示运行实验的次数，n表示每次实验所需的随机数的个数。在行内，随机数是独立分布的；在行间，随机数是非常均匀的。这些随机数是用“分层取样”的方法产生的。
14．@rand(seed)
返回0和1间的伪随机数，依赖于指定的种子。典型用法是U(I+1)=@rand(U(I))。注意如果seed不变，那么产生的随机数也不变。

---

5． 变量界定函数：这类函数用来定义变量的取值范围

@bin(x)        限制x为0或1
@bnd(L,x,U)    限制L≤x≤U
@free(x)       取消对变量x的默认下界为0的限制，即x可以取任意实数
@gin(x)        限制x为整数

---

6． 集操作函数：这类函数为对集的操作提供帮助

1．@in(set_name,primitive_index_1 [,primitive_index_2,…])
如果元素在指定集中，返回1；否则返回0。
2．@index([set_name,] primitive_set_element)
该函数返回在集set_name中原始集成员primitive_set_element的索引。
如果set_name被忽略，那么LINGO将返回与primitive_set_element匹配的第一个原始集成员的索引。
如果找不到，则产生一个错误。
3．@wrap(index,limit)
该函数返回j=index-k*limit，其中k是一个整数，取适当值保证j落在区间[1，limit]内。
该函数相当于index模limit再加1。该函数在循环、多阶段计划编制中特别有用。
4．@size(set_name)
该函数返回集set_name的成员个数。在模型中明确给出集大小时最好使用该函数。
它的使用使模型更加数据中立，集大小改变时也更易维护。


例1：
sets:
  S1/A B C/;
  S2/X Y Z/;
  S3(S1,S2)/A X, A Z, B Y, C X/;
endsets
X=@in(S3,@index(S1,B),@index(S2,Y));

例2
sets:
  girls/debble,sue,alice/;
  boys/bob,joe,sue,fred/;
endsets
I1=@index(sue);
I2=@index(boys,sue);

---

7． 集循环函数：遍历集的元素，执行一定的操作的函数

集循环函数遍历整个集进行操作。其语法为
@function(setname[(set_index_list)[|conditional_qualifier]]:
expression_list);

@function相应于下面罗列的四个集循环函数之一
setname是要遍历的集；
set_ index_list是集索引列表
conditional_qualifier是用来限制集循环函数的范围
expression_list是被应用到每个集成员的表达式列表，当用的是@for函数时，expression_list可以包含多个表达式，其间用逗号隔开

例1：@for
model:
sets:
  number/1..5/:x;
endsets
  @for(number(I): x(I)=I^2);
end


例2：@sum
model:
data:
  N=6;
enddata
sets:
  number/1..N/:x;
endsets
data:
  x = 5 1 3 4 6 10;
enddata
  s=@sum(number(I) | I #le# 5: x);
end


例3：@min和@max
求向量[5，1，3，4，6，10]前5个数的最小值，后3个数的最大值。
model:
data:
  N=6;
enddata
sets:
  number/1..N/:x;
endsets
data:
  x = 5 1 3 4 6 10;
enddata
  minv=@min(number(I) | I #le# 5: x);
  maxv=@max(number(I) | I #ge# N-2: x);
end
|用来过滤条件哦

---

8． * 数据输入输出函数*：这类函数允许模型和外部数据源相联系，进行数据的输入输出

1．@file函数
    该函数用从外部文件中输入数据，可以放在模型中任何地方。该函数的语法格式为@file(’filename’)。
2.@text函数
该函数被用在数据部分用来把解输出至文本文件中。
它可以输出集成员和集属性值。其语法为
@text([’filename’])
3．@ole函数
@OLE是从EXCEL中引入或输出数据的接口函数，它是基于传输的OLE技术。
OLE传输直接在内存中传输数据，并不借助于中间文件。
当使用@OLE时，LINGO先装载EXCEL，再通知EXCEL装载指定的电子数据表，最后从电子数据表中获得Ranges。
为了使用OLE函数，必须有EXCEL5及其以上版本。
OLE函数可在数据部分和初始部分引入数据。
4．@ranged(variable_or_row_name)
为了保持最优基不变，变量的费用系数或约束行的右端项允许减少的量。
5．@rangeu(variable_or_row_name)
为了保持最优基不变，变量的费用系数或约束行的右端项允许增加的量。
6．@status()
返回LINGO求解模型结束后的状态：
0   Global Optimum（全局最优）
1   Infeasible（不可行）
2   Unbounded（无界）
3   Undetermined（不确定）
4   Feasible（可行）
5   Infeasible or Unbounded（通常需要关闭“预处理”选项后重新求解模型，以确定模型究竟是不可行还是无界）
6   Local Optimum（局部最优）
7   Locally Infeasible（局部不可行，尽管可行解可能存在，但是LINGO并没有找到一个）
8   Cutoff（目标函数的截断值被达到）
9   Numeric Error（求解器因在某约束中遇到无定义的算术运算而停止）
    通常，如果返回值不是0、4或6时，那么解将不可信，几乎不能用。该函数仅被用在模型的数据部分来输出数据。
7．@dual
    @dual(variable_or_row_name)返回变量的判别数（检验数）或约束行的对偶（影子）价格（dual prices）。




例1：
model:
!6发点8收点运输问题;
sets:
  warehouses/ @file('1_2.txt') /: capacity;
  vendors/ @file('1_2.txt') /: demand;
  links(warehouses,vendors): cost, volume;
endsets
!目标函数;
  min=@sum(links: cost*volume);
!需求约束;
  @for(vendors(J):
    @sum(warehouses(I): volume(I,J))=demand(J));
!产量约束;
  @for(warehouses(I):
    @sum(vendors(J): volume(I,J))<=capacity(I));

!这里是数据;
data:
  capacity = @file('1_2.txt') ;
  demand = @file('1_2.txt') ;
  cost = @file('1_2.txt') ;
enddata
end


模型的所有数据来自于1_2.txt文件。其内容如下：
!warehouses成员;
WH1 WH2 WH3 WH4 WH5 WH6 ~

!vendors成员;
V1 V2 V3 V4 V5 V6 V7 V8 ~

!产量;
60 55 51 43 41 52 ~

!销量;
35 37 22 32 41 32 43 38 ~

!单位运输费用矩阵;
6 2 6 7 4 2 5 9
4 9 5 3 8 5 8 2
5 2 1 9 7 4 3 3
7 6 7 3 9 2 7 1
2 3 9 5 7 2 6 5
5 5 2 2 8 1 4 3





例2：
model:
sets:
  days/mon..sun/: required,start;
endsets
data:
  !每天所需的最少职员数;
  required = 20 16 13 16 19 14 12;
  @text('d:\out.txt')=days '至少需要的职员数为' start;
enddata
!最小化每周所需职员数;
  min=@sum(days: start);
  @for(days(J):
    @sum(days(I) | I #le# 5:
      start(@wrap(J+I+2,7))) >= required(J));
end


例3：
sets:
   PRODUCT;  !产品;
   MACHINE;  !机器;
   WEEK;     !周;
   ALLOWED(PRODUCT,MACHINE,WEEK):x,y;   !允许组合及属性;
endsets
data:
   rate=0.01;
   PRODUCT,MACHINE,WEEK,ALLOWED,x,y=@OLE('D:\IMPORT.XLS');
   @OLE('D:\IMPORT.XLS')=rate;
enddata

---

9． 辅助函数：各种杂类函数

1.@if(logical_condition,true_result,false_result)
@if函数将评价一个逻辑表达式logical_condition，如果为真，返回true_ result，否则返回false_result。
  2．@warn(’text’,logical_condition)
如果逻辑条件logical_condition为真，则产生一个内容为’text’的信息框。


例2：
model:
  x=1;
  @warn('x是正数',x #gt# 0); 
end

例1见下

model:
  min=fx+fy;
  fx=@if(x #gt# 0, 100,0)+2*x;
  fy=@if(y #gt# 0,60,0)+3*y;
  x+y>=30;
end