数组排序系列（3）

版权声明：本文为博主原创文章，转载请注明出处。 https://blog.csdn.net/taller_2000/article/details/82721894

工作表排序法

前面两篇文章分享了两种纯算法实现的排序方法。这次介绍一个其他类型的方法，Excel的排序功能非常简单实用，即使是小白用户也可以熟练操作，在VBA中借助工作表排序也就成为一个实现数值排序的好方法。

Sub SortInSheet()
    Dim aintData(1 To 10) As Variant
    Dim avntData As Variant
    Dim i As Integer
    Dim intLB As Integer
    Dim intUB As Integer
    Dim rngData As Range
    intLB = LBound(aintData)
    intUB = UBound(aintData)
    For i = intLB To intUB
        aintData(i) = Application.WorksheetFunction.RandBetween(1, 100)
    Next i
    Debug.Print "Original Data: " & Join(aintData, ",")
    With ActiveSheet
        .Columns(1).Clear
        Set rngData = .[a1].Resize(intUB - intLB + 1, 1)
        rngData.Value = Application.Transpose(aintData)
        With .Sort
            .SortFields.Clear
            .SortFields.Add Key:=rngData, _
                                SortOn:=xlSortOnValues, _
                                Order:=xlAscending, _
                                DataOption:=xlSortNormal
            .SetRange rngData
            .Header = xlNo
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
    End With
    avntData = Application.Transpose(rngData.Value)
    Debug.Print "After Sort: " & Join(avntData, ",")
End Sub

运行代码结果如下。

Original Data: 72,8,53,2,38,51,39,63,77,33
After Sort: 2,8,33,38,39,51,53,63,72,77

代码解析：
第15行代码清空工作表的第1列用于后续的排序操作。
第16行代码根据数组元素的个数确定单元格区域的大小。
第17行代码将数值元素写入单元格区域。
第18行到第30行代码调用工作表的排序功能。
第19行代码清空排序字段。
第20行到第23行代码添加排序字段，其中Order参数指定为升序排序。
第24行代码设置排序单元格区域。
第25行代码指定数据区域不包含表头。
第21行代码指定忽略大小先区别。
第29行代码执行排序操作。
第32行代码将排序后的数据加载到数组中。

---

此示例代码实现的是升序排序，如需使用降序，那么只需要修改第22行代码如下。

Order:=xlDescending

---

相关文章链接：

数组排序系列（1）-- 冒泡法
数组排序系列（2）-- 极值法
数组排序系列（3）-- 工作表排序法
数组排序系列（4）-- JavaScript排序法（数字升序）
数组排序系列（5）-- JavaScript排序法（数字降序）
数组排序系列（6）-- JavaScript排序法（字符排序）